只要點兩下，升級電腦後完成所有驅動程式的安裝

        最近電腦需要升級，需要將原先Windows 10 升級到Windows 11。過去，總是要依據原先主機的型號，到原廠官方網站。將驅動程式一個個下載好。等到windows升級完成，再將驅動程式一個個裝好。總覺得很累人，是否有方式能夠讓我只要點兩下，升級電腦後完成所有驅動程式的安裝

下載檔案。解壓密碼：demo1234

使用步驟教學：

單機測試步驟：

1.下載檔案，解壓縮。解壓密碼：demo1234

2.匯出驅動設定檔->點選ExportDriverConf.bat

3.將桌面整個InstallDriver資料夾搬到隨身碟

4.升級Windows 11

5.將隨身碟內InstallDriver資料夾搬到桌面

6.匯入驅動設定檔->點選ImportDriverConf.bat

程式目的：匯出所有驅動設定檔inf 到所在的資料夾內的config

程式名稱：ExportDriverConf.bat

程式內容：

@echo off

REM ---------------以下是程式碼,不需更改---------------

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

if '%errorlevel%' NEQ '0' (

echo Requesting administrative privileges...

goto UACPrompt

) else ( goto gotAdmin )

:UACPrompt

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"

echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

"%temp%\getadmin.vbs"

exit /B

:gotAdmin

if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs"

pushd "%CD%"

CD /D "%~dp0"

echo ===============================

echo 正在匯出驅動程式（Dism）

echo 匯到：%~dp0config

echo ===============================

if not exist "%~dp0config" mkdir "%~dp0config"

dism /online /export-driver /destination:"%~dp0config"

echo 驅動匯出完成

pause

exit

程式目的：匯入config資料夾內所有驅動設定檔inf

程式名稱：ImportDriverConf.bat

程式內容：

@echo off

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

if '%errorlevel%' NEQ '0' (

echo Requesting administrative privileges...

goto UACPrompt

) else ( goto gotAdmin )

:UACPrompt

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"

echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

"%temp%\getadmin.vbs"

exit /B

:gotAdmin

if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs"

CD /D "%~dp0"

echo ===============================

echo 正在匯入驅動程式（PnPUtil）

echo 來源：%~dp0config

echo ===============================

if not exist "%~dp0config" (

    echo 找不到 config 資料夾！

    pause

    exit

)

pnputil /add-driver "%~dp0config\*.inf" /subdirs /install

echo.

echo 驅動匯入完成

echo 建議重新開機

pause

exit

資料來源：
1.如何在 Windows 系統中將驅動程式匯入和匯出到另一台電腦