資訊組長管理電腦教室。遇到學生上FB、遊戲網站時，需要對hosts 做修改。於是編輯好hosts，要下載自己編輯好的hosts到學生機上的hosts。總是要經過好幾道手續，點好幾次滑鼠，才能到。那有沒有比較好的方法，能夠解決？
有沒有一個更快的方式，讓我只要點兩下，就可以將C:\Windows\System32\drivers\etc\hosts 更名hosts_今天日期後，再複製手上的hosts到C:\Windows\System32\drivers\etc\。一氣呵成。
教學影片：
目的：
1.將C:\Windows\System32\drivers\etc\hosts 更名hosts_今天日期(當作備份)
2.複製手上的hosts到C:\Windows\System32\drivers\etc\。
檔案名稱：CopyHosts2EtcBK.bat
檔案內容：
@echo off
REM ---------------以下是程式碼,不需更改---------------
REM :: BatchGotAdmin (Run as Admin code starts)
REM --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
REM :: BatchGotAdmin (Run as Admin code ends)
REM :: Your codes should start from the following line
REM 取得今天的年、月、日 (自動補零)
SET TodayYear=%date:~0,4%
SET TodayMonthP0=%date:~5,2%
SET TodayDayP0=%date:~8,2%
REM 設定現在所處的目錄與系統目錄C:\Windows\System32\drivers\etc\
set NowDir=%~dp0
set TargetDir=C:\Windows\System32\drivers\etc\
REM 到系統目錄C:\Windows\System32\drivers\etc\
cd %TargetDir%
REM 更改檔名hosts hosts_今天日期(年月日)
rename hosts hosts_%TodayYear%_%TodayMonthP0%_%TodayDayP0%
REM 複製現在所處的目錄的hosts 到系統目錄C:\Windows\System32\drivers\etc\hosts
copy %NowDir%hosts hosts
exit
目的：
1.將手上的hosts取代C:\Windows\System32\drivers\etc\hosts。
檔案名稱：CopyHosts2Etc.bat
檔案內容：
REM ---------------以下是程式碼,不需更改---------------
@echo off
REM 設定現在所處的目錄與系統目錄C:\Windows\System32\drivers\etc\
set NowDir=%~dp0
set TargetDir=C:\Windows\System32\drivers\etc\
REM 複製現在所處的目錄的hosts 到系統目錄C:\Windows\System32\drivers\etc\hosts
copy %NowDir%hosts %TargetDir%hosts
exit
沒有留言:
張貼留言